10 REM ************************
   20 REM BASIC Program Autoloader
   30 REM     By Peter Hopkins
   40 REM ************************
   50 REM NC200 Version : 10/8/00
   60 REM Save this program as AUTO
   70 REM so that it runs automatically
   80 REM upon entering BBC BASIC.
   90 REM Downloaded from Tim's Amstrad NC Users' Site
  100 REM http:\\www.ncus.org.uk
  110 :
  120 ON ERROR PROCeror
  130 :
  140 PROCborder
  150 date$=FNdate
  160 PRINTTAB(78-(LENdate$),1)date$
  170 name$="K.70 "+date$
  180 OSCLI(name$)
  190 X=OPENOUT"Date$.Dat":PRINT# X,date$:CLOSE# X
  200 PROCmenu
  210 END
  220 DEFFNdate
  230 RESTORE340:FORJ%=1TO13:READinfo$:IF MID$(TIME$,8,3)=LEFT$(info$,3)THEN month$=info$
  240 NEXT
  250 RESTORE370:FORJ%=1TO8:READ info$:IF LEFT$(TIME$,3)=LEFT$(info$,3) THEN day$=info$
  260 NEXT
  270 day=VAL(MID$(TIME$,6,1)):day1=VAL(MID$(TIME$,5,2))
  280 IF day=0 OR day>3 abb$="th"
  290 IF day=1 abb$="st"
  300 IF day=2 abb$="nd"
  310 IF day=3 abb$="rd"
  320 IF day1=10 OR day1=11 OR day1=12 OR day1=13 abb$="th"
  330 date$=day$+" "+STR$(day1)+abb$+" "+month$+" "+MID$(TIME$,12,4)
  340 DATAJanuary,February,March,April
  350 DATAMay,June,July,August,September
  360 DATAOctober,November,December,End
  370 DATAMonday,Tuesday,Wednesday,Thursday,Friday,Saturday,Sunday,End
  380 =date$
  390 :
  400 DEFPROCborder
  410 CLS
  420 MOVE0,0:DRAW 0,127:DRAW 479,127:DRAW 479,0:DRAW 0,0
  430 MOVE 2,2:DRAW 2,125:DRAW 477,125:DRAW 477,2:DRAW 2,2
  440 ENDPROC
  450 END
  460 :
  470 DEFPROCmenu
  480 RESTORE570
  490 FOR I%=1TO12
  500   READ info$
  510   IF I%<7 PRINTTAB(2,I%+I%+1)"(";I%;") ";info$
  520   IF I%>6  PRINTTAB(40,I%+I%-11)"(";~(I%);") ";info$
  530 NEXT
  540 PROCselect
  550 ENDPROC
  560 :
  570 DATABasic Program1,Basic Program2,Basic Program3,Basic Program4
  580 DATABasic Program5,Basic Program6,Basic Program7,Basic Program8
  590 DATABasic Program9,Basic ProgramA,Basic ProgramB,Basic ProgramC
  600 :
  610 DEFPROCselect
  620 REPEAT
  630   REPEAT
  640     A%=INKEY(0)
  650     PRINTTAB(1,1)RIGHT$(TIME$,8)
  660     IF RIGHT$(TIME$,8)="00:00:00" RUN
  670   UNTIL A%>47 AND A%<58 OR A%>64 AND A%<68 OR A%=81 OR A%=172 OR A%=113
  680   IF A%=48 PROCbasic
  690   IF A%=49 CLS:CHAIN"Prog1.Bas"
  700   IF A%=50 CLS:CHAIN"Prog2.Bas"
  710   IF A%=51 CLS:CHAIN"Prog3.Bas"
  720   IF A%=52 CLS:CHAIN"Prog4.Bas"
  730   IF A%=53 CLS:CHAIN"Prog5.Bas"
  740   IF A%=54 CLS:CHAIN"Prog6.Bas"
  750   IF A%=55 CLS:CHAIN"Prog7.Bas"
  760   IF A%=56 CLS:CHAIN"Prog8.Bas"
  770   IF A%=57 CLS:CHAIN"Prog9.Bas"
  780   IF A%=65 CLS:CHAIN"ProgA.Bas"
  790   IF A%=66 CLS:CHAIN"ProgB.Bas"
  800   IF A%=67 CLS:CHAIN"ProgC.Bas"
  810   IF A%=172 CLS:END
  820 UNTIL A%=81OR A%=113
  830 *QUIT
  840 ENDPROC
  850 :
  860 DEFPROCbasic
  870 CLS
  880 PRINT"BBC BASIC (NC200) Version 3.12"
  890 PRINT"(C) Copyright R.T.Russell 1993"
  900 TIME=0:REPEAT:UNTIL TIME>100:CLS:NEW
  910 :
  920 DEFPROCeror
  930 PROCborder
  940 PRINT:PRINT
  950 PRINTTAB(3,7);"On Line ";CHR$17;ERL;CHR$18;" The Error Code Was ";CHR$17;"(";ERR;")";CHR$18;" Which Is ";CHR$17;:REPORT
  960 PRINTCHR$18
  970 END