10 REM ************************
   20 REM Protext to RTF Converter
   30 REM      By Mark Ray
   40 REM ************************
   50 REM NC100/200 Version 1D : 13/12/96
   60 REM Downloaded from Tim's Amstrad NC Users' Site
   70 REM http://www.ncus.org.uk
   80 REM Originally from the Amstrad Notepad Users' Web
   90 CLS
  100 PRINT '"Notepad to Rich Text Format converter"'
  110 INPUT "File to convert";I$
  120 INPUT " Output file as";O$
  130 LET O=OPENOUT(O$)
  140 LET I=OPENIN(I$)
  150 PRINT#O,"{\rtf1\ansi{\fonttbl{\f0\fs24 Times New Roman;}}"
  160 PRINT#O,"{\info{\author Notepad Converter}}\pard\plain\fs24 "
  170 LET F%=0
  180 LET F$=CHR$(&E2)+CHR$(&E9)+CHR$(&F5)+CHR$(&F3)+CHR$(&F4)+CHR$(&EC)
  190 REPEAT
  200   LET C%=BGET#I
  210   IF C%=&05 THEN PROCcodeout(BGET#I)
  220   IF C%=&0A THEN PRINT#O,"\par\fs24 "
  230   IF INSTR("{\}",CHR$(C%)) THEN BPUT#O,ASC("\")
  240   IF C%<>&05 AND C%<>&0A AND C%<>&8A THEN BPUT#O,C%
  250 UNTIL EOF#I
  260 PRINT#O,"}"
  270 CLOSE#O
  280 CLOSE#I
  290 VDU7
  300 END
  310 DEFPROCcodeout(C%)
  320 LET F%=F% EOR 2^INSTR(F$,CHR$(C%))
  330 LET A$="\plain"
  340 IF F% AND 2 THEN LET A$=A$+"\b"
  350 IF F% AND 4 THEN LET A$=A$+"\i"
  360 IF F% AND 8 THEN LET A$=A$+"\ul"
  370 IF F% AND 16 THEN LET A$=A$+"\dn"
  380 IF F% AND 32 THEN LET A$=A$+"\up"
  390 IF F% AND 64 THEN LET A$=A$+"\fs28 " ELSE LET A$=A$+"\fs24 "
  400 PRINT#O,A$
  410 ENDPROC